UDF To Send Email From Excel Worksheet

Function SendMessage(Msg As String, Subject As String, EmailTo As String, _
 Optional EmailCC As String, Optional EmailBCC As String, _ 
 Optional Attachment As String, Optional Importance As String)
'
' this will only set up the email for display, if you need to send
' in bulk use mail merge
'
Dim Outlook As Outlook.Application
Dim OutlookMsg As Outlook.MailItem
Dim OutlookRecip As Outlook.Recipient
Dim OutlookAttach As Outlook.Attachment

' create outlook session
Set Outlook = CreateObject("Outlook.Application")
' create msg
Set OutlookMsg = Outlook.CreateItem(olMailItem)

With OutlookMsg

' set basic params
.Subject = Subject
.HTMLBody = Msg

Set OutlookRecip = .Recipients.Add(EmailTo)
OutlookRecip.Type = olTo

' add cc's (if any)
    If EmailCC <> "" Then
        Set OutlookRecip = .Recipients.Add(EmailCC)
        OutlookRecip.Type = olCC
    End If

' add bcc's (if any)
    If EmailBCC <> "" Then
        Set OutlookRecip = .Recipients.Add(EmailBCC)
        OutlookRecip.Type = olBCC
    End If

' add attachments
    If Attachment <> "" Then
        Set OutlookAttach = .Attachments.Add(Attachment)
    End If

' set importance
    If Importance <> "" Then
        If Importance = "High" Then
            .Importance = olImportanceHigh
        ElseIf Importance = "Low" Then
            .Importance = olImportanceLow
        Else: .Importance = olImportanceNormal
        End If
    End If

' resolve names
    For Each OutlookRecip In .Recipients
        OutlookRecip.Resolve
    Next OutlookRecip

.Display

' .send

End With

Set Outlook = Nothing
Set OutlookRecip = Nothing
Set OutlookAttach = Nothing
Set OutlookMsg = Nothing

End Function